Mercurial > sdl-ios-xcode

view src/video/ataricommon/SDL_xbiosinterrupt.S @ 1138:fcfb783a3ca2

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Commercial-OSS-on-Solaris patch... --ryan. Date: Sun, 14 Aug 2005 23:06:40 -0500 From: Shawn Walker <binarycrusader@gmail.com> To: sdl@libsdl.org Subject: [SDL] [PATCH] Audio Detection Bug When using the OSS commercial drivers under Solaris 10, SDL will not properly initialise OSS audio support (dsp) if /dev/sound exists. Under Solaris (as far as I understand) /dev/sound is provided as a means of accessing a BSD style audio device, not the OSS device. SDL assumes that if /dev/sound exists, then it must be running on a Linux 2.4 system and should make the dsp device path /dev/sound/dsp. This is wrong. When using the OSS commercial drivers under Solaris, the dsp device is always referenced as /dev/dsp normally. My proposed fix is to stat the dsp device in /dev/sound to make sure it exists, before assuming /dev/sound/dsp as the audio device: http://icculus.org/~eviltypeguy/SDL_audiodev.patch I'm sure there may be a better way to do it, but the above patch is what worked for me. --=20 Shawn Walker, Software and Systems Analyst binarycrusader@gmail.com - http://binarycrusader.blogspot.com/
author Ryan C. Gordon <icculus@icculus.org>
date Thu, 08 Sep 2005 07:15:44 +0000
parents 0fb50bfaea7f
children c9b51268668f
line wrap: on
line source

/*
    SDL - Simple DirectMedia Layer
    Copyright (C) 1997, 1998, 1999, 2000, 2001, 2002  Sam Lantinga

    This library is free software; you can redistribute it and/or
    modify it under the terms of the GNU Library General Public
    License as published by the Free Software Foundation; either
    version 2 of the License, or (at your option) any later version.

    This library is distributed in the hope that it will be useful,
    but WITHOUT ANY WARRANTY; without even the implied warranty of
    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
    Library General Public License for more details.

    You should have received a copy of the GNU Library General Public
    License along with this library; if not, write to the Free
    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA

    Sam Lantinga
    slouken@libsdl.org
*/

#ifdef SAVE_RCSID
static char rcsid =
 "@(#) $Id$";
#endif

/*
 *	XBIOS mouse & joystick vectors
 *
 *	Patrice Mandin
 */

	.text

	.globl	_SDL_AtariXbios_Install
	.globl	_SDL_AtariXbios_Restore
	.globl	_SDL_AtariXbios_MouseVector
	.globl	_SDL_AtariXbios_JoystickVector

	.globl	_SDL_AtariXbios_mouseb
	.globl	_SDL_AtariXbios_mousex
	.globl	_SDL_AtariXbios_mousey
	.globl	_SDL_AtariXbios_joystick

/*--- Vector installer ---*/

_SDL_AtariXbios_Install:
	movel	sp@(4),a0

	/* Stop interrupts */

	movew	#0x2700,sr

	/* Save old mouse vector, set our routine */

	clrl	oldmousevector
	movel	sp@(8),d0
	beqs	no_new_mouse_vector
	movel	a0@(16),oldmousevector
	movel	d0,a0@(16)
no_new_mouse_vector:

	/* Save old joystick vector, set our routine */

	clrl	oldjoystickvector
	movel	sp@(12),d0
	beqs	no_new_joystick_vector
	movel	a0@(24),oldjoystickvector
	movel	d0,a0@(24)
no_new_joystick_vector:

	/* Restart interrupts */

	movew	#0x2300,sr

	rts

/*--- Vector restorer ---*/

_SDL_AtariXbios_Restore:
	movel	sp@(4),a0

	/* Stop interrupts */

	movew	#0x2700,sr

	/* Restore mouse vector */

	movel	oldmousevector,d0
	beqs	no_restore_mouse
	movel	d0,a0@(16)
no_restore_mouse:

	/* Restore joystick vector */

	movel	oldjoystickvector,d0
	beqs	no_restore_joystick
	movel	d0,a0@(24)
no_restore_joystick:

	/* Restart interrupts */

	movew	#0x2300,sr

	rts

/*--- Our mouse vector ---*/

	.text
	.even
	.ascii "XBRA"
	.ascii "LSDL"
	.comm	oldmousevector,4*1
_SDL_AtariXbios_MouseVector:
	movel	d0,sp@-

	/* Mouse buttons */
	moveb	(a0),d0
	andw	#3,d0
	movew	d0,_SDL_AtariXbios_mouseb

	/* X movement */
	moveb	a0@(1),d0
	extw	d0
	addw	d0,_SDL_AtariXbios_mousex

	/* Y movement */
	moveb	a0@(2),d0
	extw	d0
	addw	d0,_SDL_AtariXbios_mousey

	/* Jump through old vector */
	movel	sp@+,d0

	movel	oldmousevector,sp@-
	rts

	.data
	.even
	.comm	_SDL_AtariXbios_mousex,2*1
	.even
	.comm	_SDL_AtariXbios_mousey,2*1
	.even
	.comm	_SDL_AtariXbios_mouseb,2*1

/*--- Our joystick vector ---*/

	.text
	.even
	.ascii "XBRA"
	.ascii "LSDL"
	.comm	oldjoystickvector,4*1
_SDL_AtariXbios_JoystickVector:
	movel	d0,sp@-

	/* New joystick state */
	moveb	a0@(2),d0
	andw	#0x8f,d0
	movew	d0,_SDL_AtariXbios_joystick

	/* Jump through old vector */
	movel	sp@+,d0

	movel	oldjoystickvector,sp@-
	rts

	.data
	.even
	.comm	_SDL_AtariXbios_joystick,2*1