Mercurial > sdl-ios-xcode

comparison acinclude/ltsugar.m4 @ 3342:3da232c5980a

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Split acinclude.m4 into its constituent parts for easy upgrading
author Sam Lantinga <slouken@libsdl.org>
date Sun, 04 Oct 2009 20:44:04 +0000
parents
children
comparison
equal deleted inserted replaced
3341:710139a1692d 3342:3da232c5980a
1 ##############################################################################
2 # ltsugar.m4 -- libtool m4 base layer. -*-Autoconf-*-
3 #
4 # Copyright (C) 2004, 2005, 2007, 2008 Free Software Foundation, Inc.
5 # Written by Gary V. Vaughan, 2004
6 #
7 # This file is free software; the Free Software Foundation gives
8 # unlimited permission to copy and/or distribute it, with or without
9 # modifications, as long as this notice is preserved.
10
11 # serial 6 ltsugar.m4
12
13 # This is to help aclocal find these macros, as it can't see m4_define.
14 AC_DEFUN([LTSUGAR_VERSION], [m4_if([0.1])])
15
16
17 # lt_join(SEP, ARG1, [ARG2...])
18 # -----------------------------
19 # Produce ARG1SEPARG2...SEPARGn, omitting [] arguments and their
20 # associated separator.
21 # Needed until we can rely on m4_join from Autoconf 2.62, since all earlier
22 # versions in m4sugar had bugs.
23 m4_define([lt_join],
24 [m4_if([$#], [1], [],
25 [$#], [2], [[$2]],
26 [m4_if([$2], [], [], [[$2]_])$0([$1], m4_shift(m4_shift($@)))])])
27 m4_define([_lt_join],
28 [m4_if([$#$2], [2], [],
29 [m4_if([$2], [], [], [[$1$2]])$0([$1], m4_shift(m4_shift($@)))])])
30
31
32 # lt_car(LIST)
33 # lt_cdr(LIST)
34 # ------------
35 # Manipulate m4 lists.
36 # These macros are necessary as long as will still need to support
37 # Autoconf-2.59 which quotes differently.
38 m4_define([lt_car], [[$1]])
39 m4_define([lt_cdr],
40 [m4_if([$#], 0, [m4_fatal([$0: cannot be called without arguments])],
41 [$#], 1, [],
42 [m4_dquote(m4_shift($@))])])
43 m4_define([lt_unquote], $1)
44
45
46 # lt_append(MACRO-NAME, STRING, [SEPARATOR])
47 # ------------------------------------------
48 # Redefine MACRO-NAME to hold its former content plus `SEPARATOR'`STRING'.
49 # Note that neither SEPARATOR nor STRING are expanded; they are appended
50 # to MACRO-NAME as is (leaving the expansion for when MACRO-NAME is invoked).
51 # No SEPARATOR is output if MACRO-NAME was previously undefined (different
52 # than defined and empty).
53 #
54 # This macro is needed until we can rely on Autoconf 2.62, since earlier
55 # versions of m4sugar mistakenly expanded SEPARATOR but not STRING.
56 m4_define([lt_append],
57 [m4_define([$1],
58 m4_ifdef([$1], [m4_defn([$1])[$3]])[$2])])
59
60
61
62 # lt_combine(SEP, PREFIX-LIST, INFIX, SUFFIX1, [SUFFIX2...])
63 # ----------------------------------------------------------
64 # Produce a SEP delimited list of all paired combinations of elements of
65 # PREFIX-LIST with SUFFIX1 through SUFFIXn. Each element of the list
66 # has the form PREFIXmINFIXSUFFIXn.
67 # Needed until we can rely on m4_combine added in Autoconf 2.62.
68 m4_define([lt_combine],
69 [m4_if(m4_eval([$# > 3]), [1],
70 [m4_pushdef([_Lt_sep], [m4_define([_Lt_sep], m4_defn([lt_car]))])]]dnl
71 [[m4_foreach([_Lt_prefix], [$2],
72 [m4_foreach([_Lt_suffix],
73 ]m4_dquote(m4_dquote(m4_shift(m4_shift(m4_shift($@)))))[,
74 [_Lt_sep([$1])[]m4_defn([_Lt_prefix])[$3]m4_defn([_Lt_suffix])])])])])
75
76
77 # lt_if_append_uniq(MACRO-NAME, VARNAME, [SEPARATOR], [UNIQ], [NOT-UNIQ])
78 # -----------------------------------------------------------------------
79 # Iff MACRO-NAME does not yet contain VARNAME, then append it (delimited
80 # by SEPARATOR if supplied) and expand UNIQ, else NOT-UNIQ.
81 m4_define([lt_if_append_uniq],
82 [m4_ifdef([$1],
83 [m4_if(m4_index([$3]m4_defn([$1])[$3], [$3$2$3]), [-1],
84 [lt_append([$1], [$2], [$3])$4],
85 [$5])],
86 [lt_append([$1], [$2], [$3])$4])])
87
88
89 # lt_dict_add(DICT, KEY, VALUE)
90 # -----------------------------
91 m4_define([lt_dict_add],
92 [m4_define([$1($2)], [$3])])
93
94
95 # lt_dict_add_subkey(DICT, KEY, SUBKEY, VALUE)
96 # --------------------------------------------
97 m4_define([lt_dict_add_subkey],
98 [m4_define([$1($2:$3)], [$4])])
99
100
101 # lt_dict_fetch(DICT, KEY, [SUBKEY])
102 # ----------------------------------
103 m4_define([lt_dict_fetch],
104 [m4_ifval([$3],
105 m4_ifdef([$1($2:$3)], [m4_defn([$1($2:$3)])]),
106 m4_ifdef([$1($2)], [m4_defn([$1($2)])]))])
107
108
109 # lt_if_dict_fetch(DICT, KEY, [SUBKEY], VALUE, IF-TRUE, [IF-FALSE])
110 # -----------------------------------------------------------------
111 m4_define([lt_if_dict_fetch],
112 [m4_if(lt_dict_fetch([$1], [$2], [$3]), [$4],
113 [$5],
114 [$6])])
115
116
117 # lt_dict_filter(DICT, [SUBKEY], VALUE, [SEPARATOR], KEY, [...])
118 # --------------------------------------------------------------
119 m4_define([lt_dict_filter],
120 [m4_if([$5], [], [],
121 [lt_join(m4_quote(m4_default([$4], [[, ]])),
122 lt_unquote(m4_split(m4_normalize(m4_foreach(_Lt_key, lt_car([m4_shiftn(4, $@)]),
123 [lt_if_dict_fetch([$1], _Lt_key, [$2], [$3], [_Lt_key ])])))))])[]dnl
124 ])
125