Mercurial > sdl-ios-xcode

comparison acinclude/ltdl.m4 @ 3342:3da232c5980a

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Split acinclude.m4 into its constituent parts for easy upgrading
author Sam Lantinga <slouken@libsdl.org>
date Sun, 04 Oct 2009 20:44:04 +0000
parents
children 437378d409b1
comparison
equal deleted inserted replaced
3341:710139a1692d 3342:3da232c5980a
1 ##############################################################################
2 # ltdl.m4 - Configure ltdl for the target system. -*-Autoconf-*-
3 #
4 # Copyright (C) 1999-2006, 2007, 2008 Free Software Foundation, Inc.
5 # Written by Thomas Tanner, 1999
6 #
7 # This file is free software; the Free Software Foundation gives
8 # unlimited permission to copy and/or distribute it, with or without
9 # modifications, as long as this notice is preserved.
10
11 # serial 17 LTDL_INIT
12
13 # LT_CONFIG_LTDL_DIR(DIRECTORY, [LTDL-MODE])
14 # ------------------------------------------
15 # DIRECTORY contains the libltdl sources. It is okay to call this
16 # function multiple times, as long as the same DIRECTORY is always given.
17 AC_DEFUN([LT_CONFIG_LTDL_DIR],
18 [AC_BEFORE([$0], [LTDL_INIT])
19 _$0($*)
20 ])# LT_CONFIG_LTDL_DIR
21
22 # We break this out into a separate macro, so that we can call it safely
23 # internally without being caught accidentally by the sed scan in libtoolize.
24 m4_defun([_LT_CONFIG_LTDL_DIR],
25 [dnl remove trailing slashes
26 m4_pushdef([_ARG_DIR], m4_bpatsubst([$1], [/*$]))
27 m4_case(_LTDL_DIR,
28 [], [dnl only set lt_ltdl_dir if _ARG_DIR is not simply `.'
29 m4_if(_ARG_DIR, [.],
30 [],
31 [m4_define([_LTDL_DIR], _ARG_DIR)
32 _LT_SHELL_INIT([lt_ltdl_dir=']_ARG_DIR['])])],
33 [m4_if(_ARG_DIR, _LTDL_DIR,
34 [],
35 [m4_fatal([multiple libltdl directories: `]_LTDL_DIR[', `]_ARG_DIR['])])])
36 m4_popdef([_ARG_DIR])
37 ])# _LT_CONFIG_LTDL_DIR
38
39 # Initialise:
40 m4_define([_LTDL_DIR], [])
41
42
43 # _LT_BUILD_PREFIX
44 # ----------------
45 # If Autoconf is new enough, expand to `${top_build_prefix}', otherwise
46 # to `${top_builddir}/'.
47 m4_define([_LT_BUILD_PREFIX],
48 [m4_ifdef([AC_AUTOCONF_VERSION],
49 [m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.62]),
50 [-1], [m4_ifdef([_AC_HAVE_TOP_BUILD_PREFIX],
51 [${top_build_prefix}],
52 [${top_builddir}/])],
53 [${top_build_prefix}])],
54 [${top_builddir}/])[]dnl
55 ])
56
57
58 # LTDL_CONVENIENCE
59 # ----------------
60 # sets LIBLTDL to the link flags for the libltdl convenience library and
61 # LTDLINCL to the include flags for the libltdl header and adds
62 # --enable-ltdl-convenience to the configure arguments. Note that
63 # AC_CONFIG_SUBDIRS is not called here. LIBLTDL will be prefixed with
64 # '${top_build_prefix}' if available, otherwise with '${top_builddir}/',
65 # and LTDLINCL will be prefixed with '${top_srcdir}/' (note the single
66 # quotes!). If your package is not flat and you're not using automake,
67 # define top_build_prefix, top_builddir, and top_srcdir appropriately
68 # in your Makefiles.
69 AC_DEFUN([LTDL_CONVENIENCE],
70 [AC_BEFORE([$0], [LTDL_INIT])dnl
71 dnl Although the argument is deprecated and no longer documented,
72 dnl LTDL_CONVENIENCE used to take a DIRECTORY orgument, if we have one
73 dnl here make sure it is the same as any other declaration of libltdl's
74 dnl location! This also ensures lt_ltdl_dir is set when configure.ac is
75 dnl not yet using an explicit LT_CONFIG_LTDL_DIR.
76 m4_ifval([$1], [_LT_CONFIG_LTDL_DIR([$1])])dnl
77 _$0()
78 ])# LTDL_CONVENIENCE
79
80 # AC_LIBLTDL_CONVENIENCE accepted a directory argument in older libtools,
81 # now we have LT_CONFIG_LTDL_DIR:
82 AU_DEFUN([AC_LIBLTDL_CONVENIENCE],
83 [_LT_CONFIG_LTDL_DIR([m4_default([$1], [libltdl])])
84 _LTDL_CONVENIENCE])
85
86 dnl aclocal-1.4 backwards compatibility:
87 dnl AC_DEFUN([AC_LIBLTDL_CONVENIENCE], [])
88
89
90 # _LTDL_CONVENIENCE
91 # -----------------
92 # Code shared by LTDL_CONVENIENCE and LTDL_INIT([convenience]).
93 m4_defun([_LTDL_CONVENIENCE],
94 [case $enable_ltdl_convenience in
95 no) AC_MSG_ERROR([this package needs a convenience libltdl]) ;;
96 "") enable_ltdl_convenience=yes
97 ac_configure_args="$ac_configure_args --enable-ltdl-convenience" ;;
98 esac
99 LIBLTDL='_LT_BUILD_PREFIX'"${lt_ltdl_dir+$lt_ltdl_dir/}libltdlc.la"
100 LTDLDEPS=$LIBLTDL
101 LTDLINCL='-I${top_srcdir}'"${lt_ltdl_dir+/$lt_ltdl_dir}"
102
103 AC_SUBST([LIBLTDL])
104 AC_SUBST([LTDLDEPS])
105 AC_SUBST([LTDLINCL])
106
107 # For backwards non-gettext consistent compatibility...
108 INCLTDL="$LTDLINCL"
109 AC_SUBST([INCLTDL])
110 ])# _LTDL_CONVENIENCE
111
112
113 # LTDL_INSTALLABLE
114 # ----------------
115 # sets LIBLTDL to the link flags for the libltdl installable library
116 # and LTDLINCL to the include flags for the libltdl header and adds
117 # --enable-ltdl-install to the configure arguments. Note that
118 # AC_CONFIG_SUBDIRS is not called from here. If an installed libltdl
119 # is not found, LIBLTDL will be prefixed with '${top_build_prefix}' if
120 # available, otherwise with '${top_builddir}/', and LTDLINCL will be
121 # prefixed with '${top_srcdir}/' (note the single quotes!). If your
122 # package is not flat and you're not using automake, define top_build_prefix,
123 # top_builddir, and top_srcdir appropriately in your Makefiles.
124 # In the future, this macro may have to be called after LT_INIT.
125 AC_DEFUN([LTDL_INSTALLABLE],
126 [AC_BEFORE([$0], [LTDL_INIT])dnl
127 dnl Although the argument is deprecated and no longer documented,
128 dnl LTDL_INSTALLABLE used to take a DIRECTORY orgument, if we have one
129 dnl here make sure it is the same as any other declaration of libltdl's
130 dnl location! This also ensures lt_ltdl_dir is set when configure.ac is
131 dnl not yet using an explicit LT_CONFIG_LTDL_DIR.
132 m4_ifval([$1], [_LT_CONFIG_LTDL_DIR([$1])])dnl
133 _$0()
134 ])# LTDL_INSTALLABLE
135
136 # AC_LIBLTDL_INSTALLABLE accepted a directory argument in older libtools,
137 # now we have LT_CONFIG_LTDL_DIR:
138 AU_DEFUN([AC_LIBLTDL_INSTALLABLE],
139 [_LT_CONFIG_LTDL_DIR([m4_default([$1], [libltdl])])
140 _LTDL_INSTALLABLE])
141
142 dnl aclocal-1.4 backwards compatibility:
143 dnl AC_DEFUN([AC_LIBLTDL_INSTALLABLE], [])
144
145
146 # _LTDL_INSTALLABLE
147 # -----------------
148 # Code shared by LTDL_INSTALLABLE and LTDL_INIT([installable]).
149 m4_defun([_LTDL_INSTALLABLE],
150 [if test -f $prefix/lib/libltdl.la; then
151 lt_save_LDFLAGS="$LDFLAGS"
152 LDFLAGS="-L$prefix/lib $LDFLAGS"
153 AC_CHECK_LIB([ltdl], [lt_dlinit], [lt_lib_ltdl=yes])
154 LDFLAGS="$lt_save_LDFLAGS"
155 if test x"${lt_lib_ltdl-no}" = xyes; then
156 if test x"$enable_ltdl_install" != xyes; then
157 # Don't overwrite $prefix/lib/libltdl.la without --enable-ltdl-install
158 AC_MSG_WARN([not overwriting libltdl at $prefix, force with `--enable-ltdl-install'])
159 enable_ltdl_install=no
160 fi
161 elif test x"$enable_ltdl_install" = xno; then
162 AC_MSG_WARN([libltdl not installed, but installation disabled])
163 fi
164 fi
165
166 # If configure.ac declared an installable ltdl, and the user didn't override
167 # with --disable-ltdl-install, we will install the shipped libltdl.
168 case $enable_ltdl_install in
169 no) ac_configure_args="$ac_configure_args --enable-ltdl-install=no"
170 LIBLTDL="-lltdl"
171 LTDLDEPS=
172 LTDLINCL=
173 ;;
174 *) enable_ltdl_install=yes
175 ac_configure_args="$ac_configure_args --enable-ltdl-install"
176 LIBLTDL='_LT_BUILD_PREFIX'"${lt_ltdl_dir+$lt_ltdl_dir/}libltdl.la"
177 LTDLDEPS=$LIBLTDL
178 LTDLINCL='-I${top_srcdir}'"${lt_ltdl_dir+/$lt_ltdl_dir}"
179 ;;
180 esac
181
182 AC_SUBST([LIBLTDL])
183 AC_SUBST([LTDLDEPS])
184 AC_SUBST([LTDLINCL])
185
186 # For backwards non-gettext consistent compatibility...
187 INCLTDL="$LTDLINCL"
188 AC_SUBST([INCLTDL])
189 ])# LTDL_INSTALLABLE
190
191
192 # _LTDL_MODE_DISPATCH
193 # -------------------
194 m4_define([_LTDL_MODE_DISPATCH],
195 [dnl If _LTDL_DIR is `.', then we are configuring libltdl itself:
196 m4_if(_LTDL_DIR, [],
197 [],
198 dnl if _LTDL_MODE was not set already, the default value is `subproject':
199 [m4_case(m4_default(_LTDL_MODE, [subproject]),
200 [subproject], [AC_CONFIG_SUBDIRS(_LTDL_DIR)
201 _LT_SHELL_INIT([lt_dlopen_dir="$lt_ltdl_dir"])],
202 [nonrecursive], [_LT_SHELL_INIT([lt_dlopen_dir="$lt_ltdl_dir"; lt_libobj_prefix="$lt_ltdl_dir/"])],
203 [recursive], [],
204 [m4_fatal([unknown libltdl mode: ]_LTDL_MODE)])])dnl
205 dnl Be careful not to expand twice:
206 m4_define([$0], [])
207 ])# _LTDL_MODE_DISPATCH
208
209
210 # _LT_LIBOBJ(MODULE_NAME)
211 # -----------------------
212 # Like AC_LIBOBJ, except that MODULE_NAME goes into _LT_LIBOBJS instead
213 # of into LIBOBJS.
214 AC_DEFUN([_LT_LIBOBJ], [
215 m4_pattern_allow([^_LT_LIBOBJS$])
216 _LT_LIBOBJS="$_LT_LIBOBJS $1.$ac_objext"
217 ])# _LT_LIBOBJS
218
219
220 # LTDL_INIT([OPTIONS])
221 # --------------------
222 # Clients of libltdl can use this macro to allow the installer to
223 # choose between a shipped copy of the ltdl sources or a preinstalled
224 # version of the library. If the shipped ltdl sources are not in a
225 # subdirectory named libltdl, the directory name must be given by
226 # LT_CONFIG_LTDL_DIR.
227 AC_DEFUN([LTDL_INIT],
228 [dnl Parse OPTIONS
229 _LT_SET_OPTIONS([$0], [$1])
230
231 dnl We need to keep our own list of libobjs separate from our parent project,
232 dnl and the easiest way to do that is redefine the AC_LIBOBJs macro while
233 dnl we look for our own LIBOBJs.
234 m4_pushdef([AC_LIBOBJ], m4_defn([_LT_LIBOBJ]))
235 m4_pushdef([AC_LIBSOURCES])
236
237 dnl If not otherwise defined, default to the 1.5.x compatible subproject mode:
238 m4_if(_LTDL_MODE, [],
239 [m4_define([_LTDL_MODE], m4_default([$2], [subproject]))
240 m4_if([-1], [m4_bregexp(_LTDL_MODE, [\(subproject\|\(non\)?recursive\)])],
241 [m4_fatal([unknown libltdl mode: ]_LTDL_MODE)])])
242
243 AC_ARG_WITH([included_ltdl],
244 [AS_HELP_STRING([--with-included-ltdl],
245 [use the GNU ltdl sources included here])])
246
247 if test "x$with_included_ltdl" != xyes; then
248 # We are not being forced to use the included libltdl sources, so
249 # decide whether there is a useful installed version we can use.
250 AC_CHECK_HEADER([ltdl.h],
251 [AC_CHECK_DECL([lt_dlinterface_register],
252 [AC_CHECK_LIB([ltdl], [lt_dladvise_preload],
253 [with_included_ltdl=no],
254 [with_included_ltdl=yes])],
255 [with_included_ltdl=yes],
256 [AC_INCLUDES_DEFAULT
257 #include <ltdl.h>])],
258 [with_included_ltdl=yes],
259 [AC_INCLUDES_DEFAULT]
260 )
261 fi
262
263 dnl If neither LT_CONFIG_LTDL_DIR, LTDL_CONVENIENCE nor LTDL_INSTALLABLE
264 dnl was called yet, then for old times' sake, we assume libltdl is in an
265 dnl eponymous directory:
266 AC_PROVIDE_IFELSE([LT_CONFIG_LTDL_DIR], [], [_LT_CONFIG_LTDL_DIR([libltdl])])
267
268 AC_ARG_WITH([ltdl_include],
269 [AS_HELP_STRING([--with-ltdl-include=DIR],
270 [use the ltdl headers installed in DIR])])
271
272 if test -n "$with_ltdl_include"; then
273 if test -f "$with_ltdl_include/ltdl.h"; then :
274 else
275 AC_MSG_ERROR([invalid ltdl include directory: `$with_ltdl_include'])
276 fi
277 else
278 with_ltdl_include=no
279 fi
280
281 AC_ARG_WITH([ltdl_lib],
282 [AS_HELP_STRING([--with-ltdl-lib=DIR],
283 [use the libltdl.la installed in DIR])])
284
285 if test -n "$with_ltdl_lib"; then
286 if test -f "$with_ltdl_lib/libltdl.la"; then :
287 else
288 AC_MSG_ERROR([invalid ltdl library directory: `$with_ltdl_lib'])
289 fi
290 else
291 with_ltdl_lib=no
292 fi
293
294 case ,$with_included_ltdl,$with_ltdl_include,$with_ltdl_lib, in
295 ,yes,no,no,)
296 m4_case(m4_default(_LTDL_TYPE, [convenience]),
297 [convenience], [_LTDL_CONVENIENCE],
298 [installable], [_LTDL_INSTALLABLE],
299 [m4_fatal([unknown libltdl build type: ]_LTDL_TYPE)])
300 ;;
301 ,no,no,no,)
302 # If the included ltdl is not to be used, then use the
303 # preinstalled libltdl we found.
304 AC_DEFINE([HAVE_LTDL], [1],
305 [Define this if a modern libltdl is already installed])
306 LIBLTDL=-lltdl
307 LTDLDEPS=
308 LTDLINCL=
309 ;;
310 ,no*,no,*)
311 AC_MSG_ERROR([`--with-ltdl-include' and `--with-ltdl-lib' options must be used together])
312 ;;
313 *) with_included_ltdl=no
314 LIBLTDL="-L$with_ltdl_lib -lltdl"
315 LTDLDEPS=
316 LTDLINCL="-I$with_ltdl_include"
317 ;;
318 esac
319 INCLTDL="$LTDLINCL"
320
321 # Report our decision...
322 AC_MSG_CHECKING([where to find libltdl headers])
323 AC_MSG_RESULT([$LTDLINCL])
324 AC_MSG_CHECKING([where to find libltdl library])
325 AC_MSG_RESULT([$LIBLTDL])
326
327 _LTDL_SETUP
328
329 dnl restore autoconf definition.
330 m4_popdef([AC_LIBOBJ])
331 m4_popdef([AC_LIBSOURCES])
332
333 AC_CONFIG_COMMANDS_PRE([
334 _ltdl_libobjs=
335 _ltdl_ltlibobjs=
336 if test -n "$_LT_LIBOBJS"; then
337 # Remove the extension.
338 _lt_sed_drop_objext='s/\.o$//;s/\.obj$//'
339 for i in `for i in $_LT_LIBOBJS; do echo "$i"; done | sed "$_lt_sed_drop_objext" | sort -u`; do
340 _ltdl_libobjs="$_ltdl_libobjs $lt_libobj_prefix$i.$ac_objext"
341 _ltdl_ltlibobjs="$_ltdl_ltlibobjs $lt_libobj_prefix$i.lo"
342 done
343 fi
344 AC_SUBST([ltdl_LIBOBJS], [$_ltdl_libobjs])
345 AC_SUBST([ltdl_LTLIBOBJS], [$_ltdl_ltlibobjs])
346 ])
347
348 # Only expand once:
349 m4_define([LTDL_INIT])
350 ])# LTDL_INIT
351
352 # Old names:
353 AU_DEFUN([AC_LIB_LTDL], [LTDL_INIT($@)])
354 AU_DEFUN([AC_WITH_LTDL], [LTDL_INIT($@)])
355 AU_DEFUN([LT_WITH_LTDL], [LTDL_INIT($@)])
356 dnl aclocal-1.4 backwards compatibility:
357 dnl AC_DEFUN([AC_LIB_LTDL], [])
358 dnl AC_DEFUN([AC_WITH_LTDL], [])
359 dnl AC_DEFUN([LT_WITH_LTDL], [])
360
361
362 # _LTDL_SETUP
363 # -----------
364 # Perform all the checks necessary for compilation of the ltdl objects
365 # -- including compiler checks and header checks. This is a public
366 # interface mainly for the benefit of libltdl's own configure.ac, most
367 # other users should call LTDL_INIT instead.
368 AC_DEFUN([_LTDL_SETUP],
369 [AC_REQUIRE([AC_PROG_CC])dnl
370 AC_REQUIRE([LT_SYS_MODULE_EXT])dnl
371 AC_REQUIRE([LT_SYS_MODULE_PATH])dnl
372 AC_REQUIRE([LT_SYS_DLSEARCH_PATH])dnl
373 AC_REQUIRE([LT_LIB_DLLOAD])dnl
374 AC_REQUIRE([LT_SYS_SYMBOL_USCORE])dnl
375 AC_REQUIRE([LT_FUNC_DLSYM_USCORE])dnl
376 AC_REQUIRE([LT_SYS_DLOPEN_DEPLIBS])dnl
377 AC_REQUIRE([gl_FUNC_ARGZ])dnl
378
379 m4_require([_LT_CHECK_OBJDIR])dnl
380 m4_require([_LT_HEADER_DLFCN])dnl
381 m4_require([_LT_CHECK_DLPREOPEN])dnl
382 m4_require([_LT_DECL_SED])dnl
383
384 dnl Don't require this, or it will be expanded earlier than the code
385 dnl that sets the variables it relies on:
386 _LT_ENABLE_INSTALL
387
388 dnl _LTDL_MODE specific code must be called at least once:
389 _LTDL_MODE_DISPATCH
390
391 # In order that ltdl.c can compile, find out the first AC_CONFIG_HEADERS
392 # the user used. This is so that ltdl.h can pick up the parent projects
393 # config.h file, The first file in AC_CONFIG_HEADERS must contain the
394 # definitions required by ltdl.c.
395 # FIXME: Remove use of undocumented AC_LIST_HEADERS (2.59 compatibility).
396 AC_CONFIG_COMMANDS_PRE([dnl
397 m4_pattern_allow([^LT_CONFIG_H$])dnl
398 m4_ifset([AH_HEADER],
399 [LT_CONFIG_H=AH_HEADER],
400 [m4_ifset([AC_LIST_HEADERS],
401 [LT_CONFIG_H=`echo "AC_LIST_HEADERS" | $SED 's,^[[ ]]*,,;s,[[ :]].*$,,'`],
402 [])])])
403 AC_SUBST([LT_CONFIG_H])
404
405 AC_CHECK_HEADERS([unistd.h dl.h sys/dl.h dld.h mach-o/dyld.h dirent.h],
406 [], [], [AC_INCLUDES_DEFAULT])
407
408 AC_CHECK_FUNCS([closedir opendir readdir], [], [AC_LIBOBJ([lt__dirent])])
409 AC_CHECK_FUNCS([strlcat strlcpy], [], [AC_LIBOBJ([lt__strl])])
410
411 AC_DEFINE_UNQUOTED([LT_LIBEXT],["$libext"],[The archive extension])
412
413 name=ltdl
414 LTDLOPEN=`eval "\\$ECHO \"$libname_spec\""`
415 AC_SUBST([LTDLOPEN])
416 ])# _LTDL_SETUP
417
418
419 # _LT_ENABLE_INSTALL
420 # ------------------
421 m4_define([_LT_ENABLE_INSTALL],
422 [AC_ARG_ENABLE([ltdl-install],
423 [AS_HELP_STRING([--enable-ltdl-install], [install libltdl])])
424
425 case ,${enable_ltdl_install},${enable_ltdl_convenience} in
426 *yes*) ;;
427 *) enable_ltdl_convenience=yes ;;
428 esac
429
430 m4_ifdef([AM_CONDITIONAL],
431 [AM_CONDITIONAL(INSTALL_LTDL, test x"${enable_ltdl_install-no}" != xno)
432 AM_CONDITIONAL(CONVENIENCE_LTDL, test x"${enable_ltdl_convenience-no}" != xno)])
433 ])# _LT_ENABLE_INSTALL
434
435
436 # LT_SYS_DLOPEN_DEPLIBS
437 # ---------------------
438 AC_DEFUN([LT_SYS_DLOPEN_DEPLIBS],
439 [AC_REQUIRE([AC_CANONICAL_HOST])dnl
440 AC_CACHE_CHECK([whether deplibs are loaded by dlopen],
441 [lt_cv_sys_dlopen_deplibs],
442 [# PORTME does your system automatically load deplibs for dlopen?
443 # or its logical equivalent (e.g. shl_load for HP-UX < 11)
444 # For now, we just catch OSes we know something about -- in the
445 # future, we'll try test this programmatically.
446 lt_cv_sys_dlopen_deplibs=unknown
447 case $host_os in
448 aix3*|aix4.1.*|aix4.2.*)
449 # Unknown whether this is true for these versions of AIX, but
450 # we want this `case' here to explicitly catch those versions.
451 lt_cv_sys_dlopen_deplibs=unknown
452 ;;
453 aix[[4-9]]*)
454 lt_cv_sys_dlopen_deplibs=yes
455 ;;
456 amigaos*)
457 case $host_cpu in
458 powerpc)
459 lt_cv_sys_dlopen_deplibs=no
460 ;;
461 esac
462 ;;
463 darwin*)
464 # Assuming the user has installed a libdl from somewhere, this is true
465 # If you are looking for one http://www.opendarwin.org/projects/dlcompat
466 lt_cv_sys_dlopen_deplibs=yes
467 ;;
468 freebsd* | dragonfly*)
469 lt_cv_sys_dlopen_deplibs=yes
470 ;;
471 gnu* | linux* | k*bsd*-gnu)
472 # GNU and its variants, using gnu ld.so (Glibc)
473 lt_cv_sys_dlopen_deplibs=yes
474 ;;
475 hpux10*|hpux11*)
476 lt_cv_sys_dlopen_deplibs=yes
477 ;;
478 interix*)
479 lt_cv_sys_dlopen_deplibs=yes
480 ;;
481 irix[[12345]]*|irix6.[[01]]*)
482 # Catch all versions of IRIX before 6.2, and indicate that we don't
483 # know how it worked for any of those versions.
484 lt_cv_sys_dlopen_deplibs=unknown
485 ;;
486 irix*)
487 # The case above catches anything before 6.2, and it's known that
488 # at 6.2 and later dlopen does load deplibs.
489 lt_cv_sys_dlopen_deplibs=yes
490 ;;
491 netbsd*)
492 lt_cv_sys_dlopen_deplibs=yes
493 ;;
494 openbsd*)
495 lt_cv_sys_dlopen_deplibs=yes
496 ;;
497 osf[[1234]]*)
498 # dlopen did load deplibs (at least at 4.x), but until the 5.x series,
499 # it did *not* use an RPATH in a shared library to find objects the
500 # library depends on, so we explicitly say `no'.
501 lt_cv_sys_dlopen_deplibs=no
502 ;;
503 osf5.0|osf5.0a|osf5.1)
504 # dlopen *does* load deplibs and with the right loader patch applied
505 # it even uses RPATH in a shared library to search for shared objects
506 # that the library depends on, but there's no easy way to know if that
507 # patch is installed. Since this is the case, all we can really
508 # say is unknown -- it depends on the patch being installed. If
509 # it is, this changes to `yes'. Without it, it would be `no'.
510 lt_cv_sys_dlopen_deplibs=unknown
511 ;;
512 osf*)
513 # the two cases above should catch all versions of osf <= 5.1. Read
514 # the comments above for what we know about them.
515 # At > 5.1, deplibs are loaded *and* any RPATH in a shared library
516 # is used to find them so we can finally say `yes'.
517 lt_cv_sys_dlopen_deplibs=yes
518 ;;
519 qnx*)
520 lt_cv_sys_dlopen_deplibs=yes
521 ;;
522 solaris*)
523 lt_cv_sys_dlopen_deplibs=yes
524 ;;
525 sysv5* | sco3.2v5* | sco5v6* | unixware* | OpenUNIX* | sysv4*uw2*)
526 libltdl_cv_sys_dlopen_deplibs=yes
527 ;;
528 esac
529 ])
530 if test "$lt_cv_sys_dlopen_deplibs" != yes; then
531 AC_DEFINE([LTDL_DLOPEN_DEPLIBS], [1],
532 [Define if the OS needs help to load dependent libraries for dlopen().])
533 fi
534 ])# LT_SYS_DLOPEN_DEPLIBS
535
536 # Old name:
537 AU_ALIAS([AC_LTDL_SYS_DLOPEN_DEPLIBS], [LT_SYS_DLOPEN_DEPLIBS])
538 dnl aclocal-1.4 backwards compatibility:
539 dnl AC_DEFUN([AC_LTDL_SYS_DLOPEN_DEPLIBS], [])
540
541
542 # LT_SYS_MODULE_EXT
543 # -----------------
544 AC_DEFUN([LT_SYS_MODULE_EXT],
545 [m4_require([_LT_SYS_DYNAMIC_LINKER])dnl
546 AC_CACHE_CHECK([which extension is used for runtime loadable modules],
547 [libltdl_cv_shlibext],
548 [
549 module=yes
550 eval libltdl_cv_shlibext=$shrext_cmds
551 ])
552 if test -n "$libltdl_cv_shlibext"; then
553 m4_pattern_allow([LT_MODULE_EXT])dnl
554 AC_DEFINE_UNQUOTED([LT_MODULE_EXT], ["$libltdl_cv_shlibext"],
555 [Define to the extension used for runtime loadable modules, say, ".so".])
556 fi
557 ])# LT_SYS_MODULE_EXT
558
559 # Old name:
560 AU_ALIAS([AC_LTDL_SHLIBEXT], [LT_SYS_MODULE_EXT])
561 dnl aclocal-1.4 backwards compatibility:
562 dnl AC_DEFUN([AC_LTDL_SHLIBEXT], [])
563
564
565 # LT_SYS_MODULE_PATH
566 # ------------------
567 AC_DEFUN([LT_SYS_MODULE_PATH],
568 [m4_require([_LT_SYS_DYNAMIC_LINKER])dnl
569 AC_CACHE_CHECK([which variable specifies run-time module search path],
570 [lt_cv_module_path_var], [lt_cv_module_path_var="$shlibpath_var"])
571 if test -n "$lt_cv_module_path_var"; then
572 m4_pattern_allow([LT_MODULE_PATH_VAR])dnl
573 AC_DEFINE_UNQUOTED([LT_MODULE_PATH_VAR], ["$lt_cv_module_path_var"],
574 [Define to the name of the environment variable that determines the run-time module search path.])
575 fi
576 ])# LT_SYS_MODULE_PATH
577
578 # Old name:
579 AU_ALIAS([AC_LTDL_SHLIBPATH], [LT_SYS_MODULE_PATH])
580 dnl aclocal-1.4 backwards compatibility:
581 dnl AC_DEFUN([AC_LTDL_SHLIBPATH], [])
582
583
584 # LT_SYS_DLSEARCH_PATH
585 # --------------------
586 AC_DEFUN([LT_SYS_DLSEARCH_PATH],
587 [m4_require([_LT_SYS_DYNAMIC_LINKER])dnl
588 AC_CACHE_CHECK([for the default library search path],
589 [lt_cv_sys_dlsearch_path],
590 [lt_cv_sys_dlsearch_path="$sys_lib_dlsearch_path_spec"])
591 if test -n "$lt_cv_sys_dlsearch_path"; then
592 sys_dlsearch_path=
593 for dir in $lt_cv_sys_dlsearch_path; do
594 if test -z "$sys_dlsearch_path"; then
595 sys_dlsearch_path="$dir"
596 else
597 sys_dlsearch_path="$sys_dlsearch_path$PATH_SEPARATOR$dir"
598 fi
599 done
600 m4_pattern_allow([LT_DLSEARCH_PATH])dnl
601 AC_DEFINE_UNQUOTED([LT_DLSEARCH_PATH], ["$sys_dlsearch_path"],
602 [Define to the system default library search path.])
603 fi
604 ])# LT_SYS_DLSEARCH_PATH
605
606 # Old name:
607 AU_ALIAS([AC_LTDL_SYSSEARCHPATH], [LT_SYS_DLSEARCH_PATH])
608 dnl aclocal-1.4 backwards compatibility:
609 dnl AC_DEFUN([AC_LTDL_SYSSEARCHPATH], [])
610
611
612 # _LT_CHECK_DLPREOPEN
613 # -------------------
614 m4_defun([_LT_CHECK_DLPREOPEN],
615 [m4_require([_LT_CMD_GLOBAL_SYMBOLS])dnl
616 AC_CACHE_CHECK([whether libtool supports -dlopen/-dlpreopen],
617 [libltdl_cv_preloaded_symbols],
618 [if test -n "$lt_cv_sys_global_symbol_pipe"; then
619 libltdl_cv_preloaded_symbols=yes
620 else
621 libltdl_cv_preloaded_symbols=no
622 fi
623 ])
624 if test x"$libltdl_cv_preloaded_symbols" = xyes; then
625 AC_DEFINE([HAVE_PRELOADED_SYMBOLS], [1],
626 [Define if libtool can extract symbol lists from object files.])
627 fi
628 ])# _LT_CHECK_DLPREOPEN
629
630
631 # LT_LIB_DLLOAD
632 # -------------
633 AC_DEFUN([LT_LIB_DLLOAD],
634 [m4_pattern_allow([^LT_DLLOADERS$])
635 LT_DLLOADERS=
636 AC_SUBST([LT_DLLOADERS])
637
638 AC_LANG_PUSH([C])
639
640 LIBADD_DLOPEN=
641 AC_SEARCH_LIBS([dlopen], [dl],
642 [AC_DEFINE([HAVE_LIBDL], [1],
643 [Define if you have the libdl library or equivalent.])
644 if test "$ac_cv_search_dlopen" != "none required" ; then
645 LIBADD_DLOPEN="-ldl"
646 fi
647 libltdl_cv_lib_dl_dlopen="yes"
648 LT_DLLOADERS="$LT_DLLOADERS ${lt_dlopen_dir+$lt_dlopen_dir/}dlopen.la"],
649 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#if HAVE_DLFCN_H
650 # include <dlfcn.h>
651 #endif
652 ]], [[dlopen(0, 0);]])],
653 [AC_DEFINE([HAVE_LIBDL], [1],
654 [Define if you have the libdl library or equivalent.])
655 libltdl_cv_func_dlopen="yes"
656 LT_DLLOADERS="$LT_DLLOADERS ${lt_dlopen_dir+$lt_dlopen_dir/}dlopen.la"],
657 [AC_CHECK_LIB([svld], [dlopen],
658 [AC_DEFINE([HAVE_LIBDL], [1],
659 [Define if you have the libdl library or equivalent.])
660 LIBADD_DLOPEN="-lsvld" libltdl_cv_func_dlopen="yes"
661 LT_DLLOADERS="$LT_DLLOADERS ${lt_dlopen_dir+$lt_dlopen_dir/}dlopen.la"])])])
662 if test x"$libltdl_cv_func_dlopen" = xyes || test x"$libltdl_cv_lib_dl_dlopen" = xyes
663 then
664 lt_save_LIBS="$LIBS"
665 LIBS="$LIBS $LIBADD_DLOPEN"
666 AC_CHECK_FUNCS([dlerror])
667 LIBS="$lt_save_LIBS"
668 fi
669 AC_SUBST([LIBADD_DLOPEN])
670
671 LIBADD_SHL_LOAD=
672 AC_CHECK_FUNC([shl_load],
673 [AC_DEFINE([HAVE_SHL_LOAD], [1],
674 [Define if you have the shl_load function.])
675 LT_DLLOADERS="$LT_DLLOADERS ${lt_dlopen_dir+$lt_dlopen_dir/}shl_load.la"],
676 [AC_CHECK_LIB([dld], [shl_load],
677 [AC_DEFINE([HAVE_SHL_LOAD], [1],
678 [Define if you have the shl_load function.])
679 LT_DLLOADERS="$LT_DLLOADERS ${lt_dlopen_dir+$lt_dlopen_dir/}shl_load.la"
680 LIBADD_SHL_LOAD="-ldld"])])
681 AC_SUBST([LIBADD_SHL_LOAD])
682
683 case $host_os in
684 darwin[[1567]].*)
685 # We only want this for pre-Mac OS X 10.4.
686 AC_CHECK_FUNC([_dyld_func_lookup],
687 [AC_DEFINE([HAVE_DYLD], [1],
688 [Define if you have the _dyld_func_lookup function.])
689 LT_DLLOADERS="$LT_DLLOADERS ${lt_dlopen_dir+$lt_dlopen_dir/}dyld.la"])
690 ;;
691 beos*)
692 LT_DLLOADERS="$LT_DLLOADERS ${lt_dlopen_dir+$lt_dlopen_dir/}load_add_on.la"
693 ;;
694 cygwin* | mingw* | os2* | pw32*)
695 AC_CHECK_DECLS([cygwin_conv_path], [], [], [[#include <sys/cygwin.h>]])
696 LT_DLLOADERS="$LT_DLLOADERS ${lt_dlopen_dir+$lt_dlopen_dir/}loadlibrary.la"
697 ;;
698 esac
699
700 AC_CHECK_LIB([dld], [dld_link],
701 [AC_DEFINE([HAVE_DLD], [1],
702 [Define if you have the GNU dld library.])
703 LT_DLLOADERS="$LT_DLLOADERS ${lt_dlopen_dir+$lt_dlopen_dir/}dld_link.la"])
704 AC_SUBST([LIBADD_DLD_LINK])
705
706 m4_pattern_allow([^LT_DLPREOPEN$])
707 LT_DLPREOPEN=
708 if test -n "$LT_DLLOADERS"
709 then
710 for lt_loader in $LT_DLLOADERS; do
711 LT_DLPREOPEN="$LT_DLPREOPEN-dlpreopen $lt_loader "
712 done
713 AC_DEFINE([HAVE_LIBDLLOADER], [1],
714 [Define if libdlloader will be built on this platform])
715 fi
716 AC_SUBST([LT_DLPREOPEN])
717
718 dnl This isn't used anymore, but set it for backwards compatibility
719 LIBADD_DL="$LIBADD_DLOPEN $LIBADD_SHL_LOAD"
720 AC_SUBST([LIBADD_DL])
721
722 AC_LANG_POP
723 ])# LT_LIB_DLLOAD
724
725 # Old name:
726 AU_ALIAS([AC_LTDL_DLLIB], [LT_LIB_DLLOAD])
727 dnl aclocal-1.4 backwards compatibility:
728 dnl AC_DEFUN([AC_LTDL_DLLIB], [])
729
730
731 # LT_SYS_SYMBOL_USCORE
732 # --------------------
733 # does the compiler prefix global symbols with an underscore?
734 AC_DEFUN([LT_SYS_SYMBOL_USCORE],
735 [m4_require([_LT_CMD_GLOBAL_SYMBOLS])dnl
736 AC_CACHE_CHECK([for _ prefix in compiled symbols],
737 [lt_cv_sys_symbol_underscore],
738 [lt_cv_sys_symbol_underscore=no
739 cat > conftest.$ac_ext <<_LT_EOF
740 void nm_test_func(){}
741 int main(){nm_test_func;return 0;}
742 _LT_EOF
743 if AC_TRY_EVAL(ac_compile); then
744 # Now try to grab the symbols.
745 ac_nlist=conftest.nm
746 if AC_TRY_EVAL(NM conftest.$ac_objext \| $lt_cv_sys_global_symbol_pipe \> $ac_nlist) && test -s "$ac_nlist"; then
747 # See whether the symbols have a leading underscore.
748 if grep '^. _nm_test_func' "$ac_nlist" >/dev/null; then
749 lt_cv_sys_symbol_underscore=yes
750 else
751 if grep '^. nm_test_func ' "$ac_nlist" >/dev/null; then
752 :
753 else
754 echo "configure: cannot find nm_test_func in $ac_nlist" >&AS_MESSAGE_LOG_FD
755 fi
756 fi
757 else
758 echo "configure: cannot run $lt_cv_sys_global_symbol_pipe" >&AS_MESSAGE_LOG_FD
759 fi
760 else
761 echo "configure: failed program was:" >&AS_MESSAGE_LOG_FD
762 cat conftest.c >&AS_MESSAGE_LOG_FD
763 fi
764 rm -rf conftest*
765 ])
766 sys_symbol_underscore=$lt_cv_sys_symbol_underscore
767 AC_SUBST([sys_symbol_underscore])
768 ])# LT_SYS_SYMBOL_USCORE
769
770 # Old name:
771 AU_ALIAS([AC_LTDL_SYMBOL_USCORE], [LT_SYS_SYMBOL_USCORE])
772 dnl aclocal-1.4 backwards compatibility:
773 dnl AC_DEFUN([AC_LTDL_SYMBOL_USCORE], [])
774
775
776 # LT_FUNC_DLSYM_USCORE
777 # --------------------
778 AC_DEFUN([LT_FUNC_DLSYM_USCORE],
779 [AC_REQUIRE([LT_SYS_SYMBOL_USCORE])dnl
780 if test x"$lt_cv_sys_symbol_underscore" = xyes; then
781 if test x"$libltdl_cv_func_dlopen" = xyes ||
782 test x"$libltdl_cv_lib_dl_dlopen" = xyes ; then
783 AC_CACHE_CHECK([whether we have to add an underscore for dlsym],
784 [libltdl_cv_need_uscore],
785 [libltdl_cv_need_uscore=unknown
786 save_LIBS="$LIBS"
787 LIBS="$LIBS $LIBADD_DLOPEN"
788 _LT_TRY_DLOPEN_SELF(
789 [libltdl_cv_need_uscore=no], [libltdl_cv_need_uscore=yes],
790 [], [libltdl_cv_need_uscore=cross])
791 LIBS="$save_LIBS"
792 ])
793 fi
794 fi
795
796 if test x"$libltdl_cv_need_uscore" = xyes; then
797 AC_DEFINE([NEED_USCORE], [1],
798 [Define if dlsym() requires a leading underscore in symbol names.])
799 fi
800 ])# LT_FUNC_DLSYM_USCORE
801
802 # Old name:
803 AU_ALIAS([AC_LTDL_DLSYM_USCORE], [LT_FUNC_DLSYM_USCORE])
804 dnl aclocal-1.4 backwards compatibility:
805 dnl AC_DEFUN([AC_LTDL_DLSYM_USCORE], [])
806
807 ##############################################################################
808 # Helper functions for option handling. -*- Autoconf -*-
809 #
810 # Copyright (C) 2004, 2005, 2007, 2008 Free Software Foundation, Inc.
811 # Written by Gary V. Vaughan, 2004
812 #
813 # This file is free software; the Free Software Foundation gives
814 # unlimited permission to copy and/or distribute it, with or without
815 # modifications, as long as this notice is preserved.
816
817 # serial 6 ltoptions.m4
818
819 # This is to help aclocal find these macros, as it can't see m4_define.
820 AC_DEFUN([LTOPTIONS_VERSION], [m4_if([1])])
821
822
823 # _LT_MANGLE_OPTION(MACRO-NAME, OPTION-NAME)
824 # ------------------------------------------
825 m4_define([_LT_MANGLE_OPTION],
826 [[_LT_OPTION_]m4_bpatsubst($1__$2, [[^a-zA-Z0-9_]], [_])])
827
828
829 # _LT_SET_OPTION(MACRO-NAME, OPTION-NAME)
830 # ---------------------------------------
831 # Set option OPTION-NAME for macro MACRO-NAME, and if there is a
832 # matching handler defined, dispatch to it. Other OPTION-NAMEs are
833 # saved as a flag.
834 m4_define([_LT_SET_OPTION],
835 [m4_define(_LT_MANGLE_OPTION([$1], [$2]))dnl
836 m4_ifdef(_LT_MANGLE_DEFUN([$1], [$2]),
837 _LT_MANGLE_DEFUN([$1], [$2]),
838 [m4_warning([Unknown $1 option `$2'])])[]dnl
839 ])
840
841
842 # _LT_IF_OPTION(MACRO-NAME, OPTION-NAME, IF-SET, [IF-NOT-SET])
843 # ------------------------------------------------------------
844 # Execute IF-SET if OPTION is set, IF-NOT-SET otherwise.
845 m4_define([_LT_IF_OPTION],
846 [m4_ifdef(_LT_MANGLE_OPTION([$1], [$2]), [$3], [$4])])
847
848
849 # _LT_UNLESS_OPTIONS(MACRO-NAME, OPTION-LIST, IF-NOT-SET)
850 # -------------------------------------------------------
851 # Execute IF-NOT-SET unless all options in OPTION-LIST for MACRO-NAME
852 # are set.
853 m4_define([_LT_UNLESS_OPTIONS],
854 [m4_foreach([_LT_Option], m4_split(m4_normalize([$2])),
855 [m4_ifdef(_LT_MANGLE_OPTION([$1], _LT_Option),
856 [m4_define([$0_found])])])[]dnl
857 m4_ifdef([$0_found], [m4_undefine([$0_found])], [$3
858 ])[]dnl
859 ])
860
861
862 # _LT_SET_OPTIONS(MACRO-NAME, OPTION-LIST)
863 # ----------------------------------------
864 # OPTION-LIST is a space-separated list of Libtool options associated
865 # with MACRO-NAME. If any OPTION has a matching handler declared with
866 # LT_OPTION_DEFINE, dispatch to that macro; otherwise complain about
867 # the unknown option and exit.
868 m4_defun([_LT_SET_OPTIONS],
869 [# Set options
870 m4_foreach([_LT_Option], m4_split(m4_normalize([$2])),
871 [_LT_SET_OPTION([$1], _LT_Option)])
872
873 m4_if([$1],[LT_INIT],[
874 dnl
875 dnl Simply set some default values (i.e off) if boolean options were not
876 dnl specified:
877 _LT_UNLESS_OPTIONS([LT_INIT], [dlopen], [enable_dlopen=no
878 ])
879 _LT_UNLESS_OPTIONS([LT_INIT], [win32-dll], [enable_win32_dll=no
880 ])
881 dnl
882 dnl If no reference was made to various pairs of opposing options, then
883 dnl we run the default mode handler for the pair. For example, if neither
884 dnl `shared' nor `disable-shared' was passed, we enable building of shared
885 dnl archives by default:
886 _LT_UNLESS_OPTIONS([LT_INIT], [shared disable-shared], [_LT_ENABLE_SHARED])
887 _LT_UNLESS_OPTIONS([LT_INIT], [static disable-static], [_LT_ENABLE_STATIC])
888 _LT_UNLESS_OPTIONS([LT_INIT], [pic-only no-pic], [_LT_WITH_PIC])
889 _LT_UNLESS_OPTIONS([LT_INIT], [fast-install disable-fast-install],
890 [_LT_ENABLE_FAST_INSTALL])
891 ])
892 ])# _LT_SET_OPTIONS
893
894
895 ## --------------------------------- ##
896 ## Macros to handle LT_INIT options. ##
897 ## --------------------------------- ##
898
899 # _LT_MANGLE_DEFUN(MACRO-NAME, OPTION-NAME)
900 # -----------------------------------------
901 m4_define([_LT_MANGLE_DEFUN],
902 [[_LT_OPTION_DEFUN_]m4_bpatsubst(m4_toupper([$1__$2]), [[^A-Z0-9_]], [_])])
903
904
905 # LT_OPTION_DEFINE(MACRO-NAME, OPTION-NAME, CODE)
906 # -----------------------------------------------
907 m4_define([LT_OPTION_DEFINE],
908 [m4_define(_LT_MANGLE_DEFUN([$1], [$2]), [$3])[]dnl
909 ])# LT_OPTION_DEFINE
910
911
912 # dlopen
913 # ------
914 LT_OPTION_DEFINE([LT_INIT], [dlopen], [enable_dlopen=yes
915 ])
916
917 AU_DEFUN([AC_LIBTOOL_DLOPEN],
918 [_LT_SET_OPTION([LT_INIT], [dlopen])
919 AC_DIAGNOSE([obsolete],
920 [$0: Remove this warning and the call to _LT_SET_OPTION when you
921 put the `dlopen' option into LT_INIT's first parameter.])
922 ])
923
924 dnl aclocal-1.4 backwards compatibility:
925 dnl AC_DEFUN([AC_LIBTOOL_DLOPEN], [])
926
927
928 # win32-dll
929 # ---------
930 # Declare package support for building win32 dll's.
931 LT_OPTION_DEFINE([LT_INIT], [win32-dll],
932 [enable_win32_dll=yes
933
934 case $host in
935 *-*-cygwin* | *-*-mingw* | *-*-pw32* | *-cegcc*)
936 AC_CHECK_TOOL(AS, as, false)
937 AC_CHECK_TOOL(DLLTOOL, dlltool, false)
938 AC_CHECK_TOOL(OBJDUMP, objdump, false)
939 ;;
940 esac
941
942 test -z "$AS" && AS=as
943 _LT_DECL([], [AS], [0], [Assembler program])dnl
944
945 test -z "$DLLTOOL" && DLLTOOL=dlltool
946 _LT_DECL([], [DLLTOOL], [0], [DLL creation program])dnl
947
948 test -z "$OBJDUMP" && OBJDUMP=objdump
949 _LT_DECL([], [OBJDUMP], [0], [Object dumper program])dnl
950 ])# win32-dll
951
952 AU_DEFUN([AC_LIBTOOL_WIN32_DLL],
953 [AC_REQUIRE([AC_CANONICAL_HOST])dnl
954 _LT_SET_OPTION([LT_INIT], [win32-dll])
955 AC_DIAGNOSE([obsolete],
956 [$0: Remove this warning and the call to _LT_SET_OPTION when you
957 put the `win32-dll' option into LT_INIT's first parameter.])
958 ])
959
960 dnl aclocal-1.4 backwards compatibility:
961 dnl AC_DEFUN([AC_LIBTOOL_WIN32_DLL], [])
962
963
964 # _LT_ENABLE_SHARED([DEFAULT])
965 # ----------------------------
966 # implement the --enable-shared flag, and supports the `shared' and
967 # `disable-shared' LT_INIT options.
968 # DEFAULT is either `yes' or `no'. If omitted, it defaults to `yes'.
969 m4_define([_LT_ENABLE_SHARED],
970 [m4_define([_LT_ENABLE_SHARED_DEFAULT], [m4_if($1, no, no, yes)])dnl
971 AC_ARG_ENABLE([shared],
972 [AS_HELP_STRING([--enable-shared@<:@=PKGS@:>@],
973 [build shared libraries @<:@default=]_LT_ENABLE_SHARED_DEFAULT[@:>@])],
974 [p=${PACKAGE-default}
975 case $enableval in
976 yes) enable_shared=yes ;;
977 no) enable_shared=no ;;
978 *)
979 enable_shared=no
980 # Look at the argument we got. We use all the common list separators.
981 lt_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR,"
982 for pkg in $enableval; do
983 IFS="$lt_save_ifs"
984 if test "X$pkg" = "X$p"; then
985 enable_shared=yes
986 fi
987 done
988 IFS="$lt_save_ifs"
989 ;;
990 esac],
991 [enable_shared=]_LT_ENABLE_SHARED_DEFAULT)
992
993 _LT_DECL([build_libtool_libs], [enable_shared], [0],
994 [Whether or not to build shared libraries])
995 ])# _LT_ENABLE_SHARED
996
997 LT_OPTION_DEFINE([LT_INIT], [shared], [_LT_ENABLE_SHARED([yes])])
998 LT_OPTION_DEFINE([LT_INIT], [disable-shared], [_LT_ENABLE_SHARED([no])])
999
1000 # Old names:
1001 AC_DEFUN([AC_ENABLE_SHARED],
1002 [_LT_SET_OPTION([LT_INIT], m4_if([$1], [no], [disable-])[shared])
1003 ])
1004
1005 AC_DEFUN([AC_DISABLE_SHARED],
1006 [_LT_SET_OPTION([LT_INIT], [disable-shared])
1007 ])
1008
1009 AU_DEFUN([AM_ENABLE_SHARED], [AC_ENABLE_SHARED($@)])
1010 AU_DEFUN([AM_DISABLE_SHARED], [AC_DISABLE_SHARED($@)])
1011
1012 dnl aclocal-1.4 backwards compatibility:
1013 dnl AC_DEFUN([AM_ENABLE_SHARED], [])
1014 dnl AC_DEFUN([AM_DISABLE_SHARED], [])
1015
1016
1017
1018 # _LT_ENABLE_STATIC([DEFAULT])
1019 # ----------------------------
1020 # implement the --enable-static flag, and support the `static' and
1021 # `disable-static' LT_INIT options.
1022 # DEFAULT is either `yes' or `no'. If omitted, it defaults to `yes'.
1023 m4_define([_LT_ENABLE_STATIC],
1024 [m4_define([_LT_ENABLE_STATIC_DEFAULT], [m4_if($1, no, no, yes)])dnl
1025 AC_ARG_ENABLE([static],
1026 [AS_HELP_STRING([--enable-static@<:@=PKGS@:>@],
1027 [build static libraries @<:@default=]_LT_ENABLE_STATIC_DEFAULT[@:>@])],
1028 [p=${PACKAGE-default}
1029 case $enableval in
1030 yes) enable_static=yes ;;
1031 no) enable_static=no ;;
1032 *)
1033 enable_static=no
1034 # Look at the argument we got. We use all the common list separators.
1035 lt_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR,"
1036 for pkg in $enableval; do
1037 IFS="$lt_save_ifs"
1038 if test "X$pkg" = "X$p"; then
1039 enable_static=yes
1040 fi
1041 done
1042 IFS="$lt_save_ifs"
1043 ;;
1044 esac],
1045 [enable_static=]_LT_ENABLE_STATIC_DEFAULT)
1046
1047 _LT_DECL([build_old_libs], [enable_static], [0],
1048 [Whether or not to build static libraries])
1049 ])# _LT_ENABLE_STATIC
1050
1051 LT_OPTION_DEFINE([LT_INIT], [static], [_LT_ENABLE_STATIC([yes])])
1052 LT_OPTION_DEFINE([LT_INIT], [disable-static], [_LT_ENABLE_STATIC([no])])
1053
1054 # Old names:
1055 AC_DEFUN([AC_ENABLE_STATIC],
1056 [_LT_SET_OPTION([LT_INIT], m4_if([$1], [no], [disable-])[static])
1057 ])
1058
1059 AC_DEFUN([AC_DISABLE_STATIC],
1060 [_LT_SET_OPTION([LT_INIT], [disable-static])
1061 ])
1062
1063 AU_DEFUN([AM_ENABLE_STATIC], [AC_ENABLE_STATIC($@)])
1064 AU_DEFUN([AM_DISABLE_STATIC], [AC_DISABLE_STATIC($@)])
1065
1066 dnl aclocal-1.4 backwards compatibility:
1067 dnl AC_DEFUN([AM_ENABLE_STATIC], [])
1068 dnl AC_DEFUN([AM_DISABLE_STATIC], [])
1069
1070
1071
1072 # _LT_ENABLE_FAST_INSTALL([DEFAULT])
1073 # ----------------------------------
1074 # implement the --enable-fast-install flag, and support the `fast-install'
1075 # and `disable-fast-install' LT_INIT options.
1076 # DEFAULT is either `yes' or `no'. If omitted, it defaults to `yes'.
1077 m4_define([_LT_ENABLE_FAST_INSTALL],
1078 [m4_define([_LT_ENABLE_FAST_INSTALL_DEFAULT], [m4_if($1, no, no, yes)])dnl
1079 AC_ARG_ENABLE([fast-install],
1080 [AS_HELP_STRING([--enable-fast-install@<:@=PKGS@:>@],
1081 [optimize for fast installation @<:@default=]_LT_ENABLE_FAST_INSTALL_DEFAULT[@:>@])],
1082 [p=${PACKAGE-default}
1083 case $enableval in
1084 yes) enable_fast_install=yes ;;
1085 no) enable_fast_install=no ;;
1086 *)
1087 enable_fast_install=no
1088 # Look at the argument we got. We use all the common list separators.
1089 lt_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR,"
1090 for pkg in $enableval; do
1091 IFS="$lt_save_ifs"
1092 if test "X$pkg" = "X$p"; then
1093 enable_fast_install=yes
1094 fi
1095 done
1096 IFS="$lt_save_ifs"
1097 ;;
1098 esac],
1099 [enable_fast_install=]_LT_ENABLE_FAST_INSTALL_DEFAULT)
1100
1101 _LT_DECL([fast_install], [enable_fast_install], [0],
1102 [Whether or not to optimize for fast installation])dnl
1103 ])# _LT_ENABLE_FAST_INSTALL
1104
1105 LT_OPTION_DEFINE([LT_INIT], [fast-install], [_LT_ENABLE_FAST_INSTALL([yes])])
1106 LT_OPTION_DEFINE([LT_INIT], [disable-fast-install], [_LT_ENABLE_FAST_INSTALL([no])])
1107
1108 # Old names:
1109 AU_DEFUN([AC_ENABLE_FAST_INSTALL],
1110 [_LT_SET_OPTION([LT_INIT], m4_if([$1], [no], [disable-])[fast-install])
1111 AC_DIAGNOSE([obsolete],
1112 [$0: Remove this warning and the call to _LT_SET_OPTION when you put
1113 the `fast-install' option into LT_INIT's first parameter.])
1114 ])
1115
1116 AU_DEFUN([AC_DISABLE_FAST_INSTALL],
1117 [_LT_SET_OPTION([LT_INIT], [disable-fast-install])
1118 AC_DIAGNOSE([obsolete],
1119 [$0: Remove this warning and the call to _LT_SET_OPTION when you put
1120 the `disable-fast-install' option into LT_INIT's first parameter.])
1121 ])
1122
1123 dnl aclocal-1.4 backwards compatibility:
1124 dnl AC_DEFUN([AC_ENABLE_FAST_INSTALL], [])
1125 dnl AC_DEFUN([AM_DISABLE_FAST_INSTALL], [])
1126
1127
1128 # _LT_WITH_PIC([MODE])
1129 # --------------------
1130 # implement the --with-pic flag, and support the `pic-only' and `no-pic'
1131 # LT_INIT options.
1132 # MODE is either `yes' or `no'. If omitted, it defaults to `both'.
1133 m4_define([_LT_WITH_PIC],
1134 [AC_ARG_WITH([pic],
1135 [AS_HELP_STRING([--with-pic],
1136 [try to use only PIC/non-PIC objects @<:@default=use both@:>@])],
1137 [pic_mode="$withval"],
1138 [pic_mode=default])
1139
1140 test -z "$pic_mode" && pic_mode=m4_default([$1], [default])
1141
1142 _LT_DECL([], [pic_mode], [0], [What type of objects to build])dnl
1143 ])# _LT_WITH_PIC
1144
1145 LT_OPTION_DEFINE([LT_INIT], [pic-only], [_LT_WITH_PIC([yes])])
1146 LT_OPTION_DEFINE([LT_INIT], [no-pic], [_LT_WITH_PIC([no])])
1147
1148 # Old name:
1149 AU_DEFUN([AC_LIBTOOL_PICMODE],
1150 [_LT_SET_OPTION([LT_INIT], [pic-only])
1151 AC_DIAGNOSE([obsolete],
1152 [$0: Remove this warning and the call to _LT_SET_OPTION when you
1153 put the `pic-only' option into LT_INIT's first parameter.])
1154 ])
1155
1156 dnl aclocal-1.4 backwards compatibility:
1157 dnl AC_DEFUN([AC_LIBTOOL_PICMODE], [])
1158
1159 ## ----------------- ##
1160 ## LTDL_INIT Options ##
1161 ## ----------------- ##
1162
1163 m4_define([_LTDL_MODE], [])
1164 LT_OPTION_DEFINE([LTDL_INIT], [nonrecursive],
1165 [m4_define([_LTDL_MODE], [nonrecursive])])
1166 LT_OPTION_DEFINE([LTDL_INIT], [recursive],
1167 [m4_define([_LTDL_MODE], [recursive])])
1168 LT_OPTION_DEFINE([LTDL_INIT], [subproject],
1169 [m4_define([_LTDL_MODE], [subproject])])
1170
1171 m4_define([_LTDL_TYPE], [])
1172 LT_OPTION_DEFINE([LTDL_INIT], [installable],
1173 [m4_define([_LTDL_TYPE], [installable])])
1174 LT_OPTION_DEFINE([LTDL_INIT], [convenience],
1175 [m4_define([_LTDL_TYPE], [convenience])])
1176